FileMove

移动或重命名一个或多个文件。

FileMove, SourcePattern, DestPattern [, Flag]

参数

SourcePattern

单个文件的名称或通配符模式, 例如 C:\Temp\*.tmp. 如果未指定绝对路径则假定 SourcePattern%A_WorkingDir% 中。

DestPattern

目标的名称或模式, 如果未指定绝对路径则假定在 %A_WorkingDir% 中. 要执行简单地移动 (保留原来的文件名), 那么只需要指定文件夹名, 如下面这些功能相同的例子所演示的那样:

FileMove, C:\*.txt, C:\My Folder
FileMove, C:\*.txt, C:\My Folder\*.*
Flag

(可选参数) 此标志决定了是否覆盖现有的文件:

0 = (默认) 不覆盖现有的文件
1 = 覆盖现有的文件

此参数可以为 表达式, 甚至是计算结果为真或假的表达式 (因为真和假内部分别保存为 1 和 0).

ErrorLevel

[v1.1.04+] 此命令失败时会抛出异常. 想了解更多信息, 请参阅 运行时错误.

ErrorLevel 被设置为由于错误而无法移动的文件数, 否则为 0. 但是, 如果源文件为单个文件 (没有通配符) 且此文件不存在, 则 ErrorLevel 被置为 0. 要判断这种情况, 请在移动前对源文件使用 IfExistFileExist().

FileCopy 不同, 移动一个文件来覆盖它自己总被认为是成功的, 即使在改写模式没有生效的情况下.

如果找到了文件, 则 A_LastError 会被设置为 0 (零) 或最近一次操作失败时调用操作系统 GetLastError() 函数的结果. 否则 A_LastError 包含了没有找到文件原因的错误码.

备注

FileMove 只移动文件. 要移动整个文件夹的内容 (它的所有文件和子文件夹), 请参照下面的示例部分. 要移动或重命名单个文件夹, 请使用 FileMoveDir.

在遇到错误后操作仍会继续进行.

尽管此命令可以移动文件到不同的卷, 但这样的操作会比在相同卷上消耗更多的时间. 这是由于在相同卷上类似于重命名, 因此快速得多.

相关

FileCopy, FileCopyDir, FileMoveDir, FileDelete

示例

FileMove, C:\My Documents\List1.txt, D:\Main Backup\  ; 移动文件而不进行重命名.
FileMove, C:\File Before.txt, C:\File After.txt  ; 重命名单个文件.
FileMove, C:\Folder1\*.txt, D:\New Folder\*.bkp  ; 移动并使用新的扩展名重命名文件.

 

; 下面的例子移动一个文件夹中所有文件和文件夹到另一个文件夹中:
ErrorCount := MoveFilesAndFolders("C:\My Folder\*.*", "D:\Folder to receive all files & folders")
if ErrorCount <> 0
    MsgBox %ErrorCount% files/folders could not be moved.

MoveFilesAndFolders(SourcePattern, DestinationFolder, DoOverwrite = false)
; 移动匹配 SourcePattern 的所有文件和文件夹到 DestinationFolder 文件夹中且
; 返回无法移动的文件/文件夹的数目. 此函数需要 v1.0.38+
; 因为它使用了 FileMoveDir 的模式 2.
{
    if DoOverwrite = 1
        DoOverwrite = 2  ; 请参阅 FileMoveDir 了解模式 2 与模式 1 的区别.
    ; 首先移动所有文件 (不是文件夹):
    FileMove, %SourcePattern%, %DestinationFolder%, %DoOverwrite%
    ErrorCount := ErrorLevel
    ; 现在移动所有文件夹:
    Loop, %SourcePattern%, 2  ; 2 表示 "只获取文件夹".
    {
        FileMoveDir, %A_LoopFileFullPath%, %DestinationFolder%\%A_LoopFileName%, %DoOverwrite%
        ErrorCount += ErrorLevel
        if ErrorLevel  ; 报告每个出现问题的文件夹名称.
            MsgBox Could not move %A_LoopFileFullPath% into %DestinationFolder%.
    }
    return ErrorCount
}