FileCopy

复制一个或多个文件。

FileCopy, SourcePattern, DestPattern [, Flag]

参数

SourcePattern

单个文件或文件夹的名称或者通配符模式, 例如 C:\Temp\*.tmp. 如果未指定绝对路径则假定 SourcePattern 在 %A_WorkingDir% 中。

DestPattern

目标的名称或模式, 如果未指定绝对路径则假定在 %A_WorkingDir% 中. 要执行简单地复制 (保留原来的文件名), 那么只需要指定文件夹名, 如下面这些功能相同的例子所演示的那样:

FileCopy, C:\*.txt, C:\My Folder

FileCopy, C:\*.txt, C:\My Folder\*.*

Flag

(可选参数) 此标志决定了是否覆盖现有的文件:

0 = (默认) 不覆盖现有的文件
1 = 覆盖现有的文件

此参数可以为 表达式, 甚至是计算结果为真或假的表达式 (因为真和假内部分别保存为 1 和 0).

ErrorLevel

[v1.1.04+] 此命令失败时会抛出异常. 想了解更多信息, 请参阅 运行时错误.

ErrorLevel 被设置为由于错误而无法复制的文件数, 否则为 0.

在这两种情况中, 如果源文件为单个文件 (没有通配符) 且此文件不存在, 则 ErrorLevel 被置为 0. 要判断这种情况, 请在复制前对源文件使用 IfExist 或 FileExist().

与 FileMove 不同, 复制一个文件来覆盖它自己总是会导致错误, 即使在改写模式生效的情况下.

如果找到了文件, 则 A_LastError 会被设置为 0 (零) 或最近一次操作失败时调用操作系统 GetLastError() 函数的结果. 否则 A_LastError 包含了没有找到文件原因的错误码.

备注

FileCopy 只复制文件. 要复制整个文件夹的内容 (它的所有文件和子文件夹), 请参照下面的示例部分. 要复制单个文件夹 (及其子文件夹), 请使用 FileCopyDir.

在遇到错误后操作仍会继续进行.

相关

FileMove, FileCopyDir, FileMoveDir, FileDelete

示例

FileCopy, C:\My Documents\List1.txt, D:\Main Backup\  ; 复制文件并保留原来的文件名. file name.
FileCopy, C:\My File.txt, C:\My File New.txt  ; 复制文件到同一个文件夹并改变文件名.
FileCopy, C:\Folder1\*.txt, D:\New Folder\*.bkp  ; 复制到新位置并改变扩展名.

; 下面的例子复制一个文件夹中所有文件和文件夹到另一个文件夹中:
ErrorCount := CopyFilesAndFolders("C:\My Folder\*.*", "D:\Folder to receive all files & folders")
if ErrorCount <> 0
    MsgBox %ErrorCount% files/folders could not be copied.

CopyFilesAndFolders(SourcePattern, DestinationFolder, DoOverwrite = false)
; 复制匹配 SourcePattern 的所有文件和文件夹到 DestinationFolder 文件夹中且
; 返回无法复制的文件/文件夹的数目.
{
    ; 首先复制所有文件 (不是文件夹):
    FileCopy, %SourcePattern%, %DestinationFolder%, %DoOverwrite%
    ErrorCount := ErrorLevel
    ; 现在复制所有文件夹:
    Loop, %SourcePattern%, 2  ; 2 表示 "只获取文件夹".
    {
        FileCopyDir, %A_LoopFileFullPath%, %DestinationFolder%\%A_LoopFileName%, %DoOverwrite%
        ErrorCount += ErrorLevel
        if ErrorLevel  ; 报告每个出现问题的文件夹名称.
            MsgBox Could not copy %A_LoopFileFullPath% into %DestinationFolder%.
    }
    return ErrorCount
}